vb.NET Insert Block and Attributes

To insert a block into AutoCAD using .NET you may also need to insert the attributes of the block after you insert the block into the drawing. Unlike in VBA, you have to insert the attributes also, they don’t come along for the ride. Below is the code to insert the block into a drawing in the current space.

    Public Function InsertBlock(ByVal blkName As String, ByVal insPt As Point3d, ByVal xBlkScale As Double, _
                                ByVal yBlkScale As Double, ByVal zBlkScale As Double, ByVal ang As Double) As ObjectId
        Dim doc As Document = Application.DocumentManager.MdiActiveDocument
        Dim db As Database = doc.Database

        Using tr As Transaction = db.TransactionManager.StartTransaction
            Dim blkTable As BlockTable = tr.GetObject(db.BlockTableId, OpenMode.ForRead)
            Dim blkObjId As ObjectId = GetBlkRefObjIdByName(blkName)

            Dim blkRef As BlockReference = New BlockReference(insPt, blkObjId)
            blkRef.SetDatabaseDefaults()
            blkRef.ScaleFactors = New Scale3d(xBlkScale, yBlkScale, zBlkScale)
            blkRef.Rotation = ang

            Dim blkTblRec As BlockTableRecord
            ' Assumes the current space was already changed to.
            blkTblRec = tr.GetObject(db.CurrentSpaceId, OpenMode.ForWrite)

            blkTblRec.AppendEntity(blkRef)
            tr.AddNewlyCreatedDBObject(blkRef, True)

            ' add the attribute definitions.
            Dim blkTblR As BlockTableRecord = blkObjId.GetObject(OpenMode.ForRead)
            For Each objId As ObjectId In blkTblR
                Dim obj As DBObject = objId.GetObject(OpenMode.ForRead)
                If TypeOf obj Is AttributeDefinition Then
                    Dim ad As AttributeDefinition = objId.GetObject(OpenMode.ForRead)
                    Dim ar As AttributeReference = New AttributeReference()
                    ar.SetAttributeFromBlock(ad, blkRef.BlockTransform)
                    ar.Position = ad.Position.TransformBy(blkRef.BlockTransform)
                    blkRef.AttributeCollection.AppendAttribute(ar)
                    tr.AddNewlyCreatedDBObject(ar, True)
                End If
            Next

            tr.Commit()
            Return blkRef.ObjectId
        End Using

    End Function